Class functions are row vectors of cyclotomics, scalar multiplication of a class function with a cyclotomic yields a class function, and the sum and the difference of two class functions with the same underlying character table (see UnderlyingCharacterTable) are again class functions of this table. The sum and the difference of a class function and a list that is not a class function are plain lists, as well as the sum and the difference of two class functions of different character tables.
gap> g:= SymmetricGroup( 4 );; tbl:= CharacterTable( g );; gap> SetName( tbl, "S4" ); irr:= Irr( g ); [ Character( S4, [ 1, 1, 1, 1, 1 ] ), Character( S4, [ 1, -1, 1, 1, -1 ] ), Character( S4, [ 2, 0, 2, -1, 0 ] ), Character( S4, [ 3, -1, -1, 0, 1 ] ), Character( S4, [ 3, 1, -1, 0, -1 ] ) ] gap> 2 * irr[1]; Character( S4, [ 2, 2, 2, 2, 2 ] ) gap> irr[2] / 7; ClassFunction( S4, [ 1/7, -1/7, 1/7, 1/7, -1/7 ] ) gap> lincomb:= irr[3] + irr[2] - irr[1]; VirtualCharacter( S4, [ 2, -2, 2, -1, -2 ] ) gap> lincomb:= lincomb + 2 * irr[1]; VirtualCharacter( S4, [ 4, 0, 4, 1, 0 ] ) gap> IsCharacter( lincomb ); true gap> lincomb; Character( S4, [ 4, 0, 4, 1, 0 ] ) gap> irr[1] + 2; [ 3, 3, 3, 3, 3 ] gap> irr[1] + [ 1, 2, 3, 4, 5 ]; [ 2, 3, 4, 5, 6 ] gap> zero:= 0 * irr[1]; VirtualCharacter( S4, [ 0, 0, 0, 0, 0 ] ) gap> zero + Z(3); [ Z(3), Z(3), Z(3), Z(3), Z(3) ] gap> irr[1] + TrivialCharacter( DihedralGroup( 8 ) ); [ 2, 2, 2, 2, 2 ]
Class functions are ring elements, the product of two class functions of the same character table is the tensor product (pointwise product) of these class functions. Thus the set of all class functions of a group forms a ring, and for any field F of cyclotomics, the F-span of a given set of class functions forms an algebra.
The product of two class functions of different tables and the product of a class function and a list that is not a class function are not defined, an error is signalled in these cases. Note that in this respect, class functions behave differently from their values lists, for which the product is defined as the standard scalar product.
gap> tens:= irr[3] * irr[4]; Character( S4, [ 6, 0, -2, 0, 0 ] ) gap> ValuesOfClassFunction( irr[3] ) * ValuesOfClassFunction( irr[4] ); 4
Class functions without zero values are invertible, the inverse is defined pointwise. As a consequence, for example groups of linear characters can be formed.
gap> tens / irr[2]; Character( S4, [ 6, 0, -2, 0, 0 ] )
The powering operator \^ has several meanings for class functions.
The power of a class function by a nonnegative integer is clearly the
tensor power.
The power of a class function by an element that normalizes the
underlying group or by a Galois automorphism is the conjugate class
function.
(As a consequence, the application of the permutation induced by such an
action cannot be denoted by \^; instead one can use Permuted,
see Permuted.)
The power of a class function by a group or a character table is the
induced class function (see InducedClassFunction).
The power of a group element by a class function is the class function
value at (the conjugacy class containing) this element.
gap> irr[3] ^ 3; Character( S4, [ 8, 0, 8, -1, 0 ] ) gap> lin:= LinearCharacters( DerivedSubgroup( g ) ); [ Character( CharacterTable( Alt( [ 1 .. 4 ] ) ), [ 1, 1, 1, 1 ] ), Character( CharacterTable( Alt( [ 1 .. 4 ] ) ), [ 1, 1, E(3), E(3)^2 ] ), Character( CharacterTable( Alt( [ 1 .. 4 ] ) ), [ 1, 1, E(3)^2, E(3) ] ) ] gap> List( lin, chi -> chi ^ (1,2) ); [ Character( CharacterTable( Alt( [ 1 .. 4 ] ) ), [ 1, 1, 1, 1 ] ), Character( CharacterTable( Alt( [ 1 .. 4 ] ) ), [ 1, 1, E(3)^2, E(3) ] ), Character( CharacterTable( Alt( [ 1 .. 4 ] ) ), [ 1, 1, E(3), E(3)^2 ] ) ] gap> Orbit( GaloisGroup( CF(3) ), lin[2] ); [ Character( CharacterTable( Alt( [ 1 .. 4 ] ) ), [ 1, 1, E(3), E(3)^2 ] ), Character( CharacterTable( Alt( [ 1 .. 4 ] ) ), [ 1, 1, E(3)^2, E(3) ] ) ] gap> lin[1]^g; Character( S4, [ 2, 0, 2, 2, 0 ] ) gap> (1,2,3)^lin[2]; E(3)^2
The characteristic of class functions is zero,
as for all list of cyclotomics.
For class functions of a p-modular character table, such as Brauer
characters, the characteristic p is given by the
UnderlyingCharacteristic (see UnderlyingCharacteristic) value of
the character table.
gap> Characteristic( irr[1] ); 0 gap> irrmod2:= Irr( g, 2 ); [ Character( BrauerTable( Sym( [ 1 .. 4 ] ), 2 ), [ 1, 1 ] ), Character( BrauerTable( Sym( [ 1 .. 4 ] ), 2 ), [ 2, -1 ] ) ] gap> Characteristic( irrmod2[1] ); 0 gap> UnderlyingCharacteristic( UnderlyingCharacterTable( irrmod2[1] ) ); 2
The operations ComplexConjugate, GaloisCyc, and Permuted return
a class function when they are called with a class function;
The complex conjugate of a class function that is known to be a (virtual)
character is again known to be a (virtual) character, and applying an
arbitrary Galois automorphism to an ordinary (virtual) character yields
a (virtual) character.
gap> ComplexConjugate( lin[2] ); Character( CharacterTable( Alt( [ 1 .. 4 ] ) ), [ 1, 1, E(3)^2, E(3) ] ) gap> GaloisCyc( lin[2], 5 ); Character( CharacterTable( Alt( [ 1 .. 4 ] ) ), [ 1, 1, E(3)^2, E(3) ] ) gap> Permuted( lin[2], (2,3,4) ); ClassFunction( CharacterTable( Alt( [ 1 .. 4 ] ) ), [ 1, E(3)^2, 1, E(3) ] )
By definition of Order for arbitrary monoid elements,
the determinantal order (see DeterminantOfCharacter) of characters
cannot be the return value of Order for characters.
One can use Order( Determinant( chi ) ) to compute the determinantal
order of the class function chi.
gap> det:= Determinant( irr[3] ); Character( S4, [ 1, -1, 1, 1, -1 ] ) gap> Order( det ); 2
[Top] [Previous] [Up] [Next] [Index]
GAP 4 manual